build.gradle.kts: moved module-info and java9 related configuration to precompiled script plugins

buildSrc/build.gradle.kts

@@ -0,0 +1,24 @@
+/*
+ * Copyright 2020 FormDev Software GmbH
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     https://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+plugins {
+	`kotlin-dsl`
+}
+
+// required for kotlin-dsl or embedded-kotlin plugins
+repositories {
+	jcenter()
+}

buildSrc/src/main/kotlin/flatlaf-java9.gradle.kts

@@ -0,0 +1,44 @@
+/*
+ * Copyright 2020 FormDev Software GmbH
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     https://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+plugins {
+	java
+}
+
+if( JavaVersion.current() >= JavaVersion.VERSION_1_9 ) {
+	sourceSets {
+		create( "java9" ) {
+			java {
+				setSrcDirs( listOf( "src/main/java9" ) )
+			}
+		}
+	}
+
+	tasks {
+		named<JavaCompile>( "compileJava9Java" ) {
+			sourceCompatibility = "9"
+			targetCompatibility = "9"
+		}
+
+		jar {
+			manifest.attributes( "Multi-Release" to "true" )
+
+			into( "META-INF/versions/9" ) {
+				from( sourceSets["java9"].output )
+			}
+		}
+	}
+}

buildSrc/src/main/kotlin/flatlaf-module-info.gradle.kts

@@ -0,0 +1,64 @@
+/*
+ * Copyright 2020 FormDev Software GmbH
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     https://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+open class ModuleInfoExtension {
+	var paths: ArrayList<String> = ArrayList()
+
+	fun dependsOn( vararg paths: String ) {
+		this.paths.addAll( paths )
+	}
+}
+
+val extension = project.extensions.create<ModuleInfoExtension>( "flatlafModuleInfo" )
+
+
+plugins {
+	java
+}
+
+if( JavaVersion.current() >= JavaVersion.VERSION_1_9 ) {
+	sourceSets {
+		create( "module-info" ) {
+			java {
+				// include "src/main/java" here to get compile errors if classes are
+				// used from other modules that are not specified in module dependencies
+				setSrcDirs( listOf( "src/main/module-info", "src/main/java" ) )
+			}
+		}
+	}
+
+	tasks {
+		named<JavaCompile>( "compileModuleInfoJava" ) {
+			sourceCompatibility = "9"
+			targetCompatibility = "9"
+
+			dependsOn( extension.paths )
+
+			options.compilerArgs.add( "--module-path" )
+			options.compilerArgs.add( configurations.runtimeClasspath.get().asPath )
+		}
+
+		jar {
+			manifest.attributes( "Multi-Release" to "true" )
+
+			into( "META-INF/versions/9" ) {
+				from( sourceSets["module-info"].output ) {
+					include( "module-info.class" )
+				}
+			}
+		}
+	}
+}

flatlaf-core/build.gradle.kts

@@ -16,56 +16,22 @@
 
 plugins {
 	`java-library`
+	`flatlaf-module-info`
+	`flatlaf-java9`
 	`maven-publish`
 	id( "com.jfrog.bintray" )
 	id( "com.jfrog.artifactory" )
 }
 
-if( JavaVersion.current() >= JavaVersion.VERSION_1_9 ) {
-	sourceSets {
-		create( "java9" ) {
-			java {
-				setSrcDirs( listOf( "src/main/java9" ) )
-			}
-		}
-		create( "module-info" ) {
-			java {
-				// include "src/main/java" here to get compile errors if classes are
-				// used from other modules that are not specified in module dependencies
-				setSrcDirs( listOf( "src/main/module-info", "src/main/java" ) )
-			}
-		}
-	}
-}
-
 java {
 	withSourcesJar()
 	withJavadocJar()
 }
 
 tasks {
-	if( JavaVersion.current() >= JavaVersion.VERSION_1_9 ) {
-		named<JavaCompile>( "compileModuleInfoJava" ) {
-			sourceCompatibility = "9"
-			targetCompatibility = "9"
-		}
-	}
-
 	jar {
 		archiveBaseName.set( "flatlaf" )
 
-		if( JavaVersion.current() >= JavaVersion.VERSION_1_9 ) {
-			manifest.attributes( "Multi-Release" to "true" )
-
-			into( "META-INF/versions/9" ) {
-				from( sourceSets["java9"].output )
-			}
-
-			from( sourceSets["module-info"].output ) {
-				include( "module-info.class" )
-			}
-		}
-
 		doLast {
 			ReorderJarEntries.reorderJarEntries( outputs.files.singleFile );
 		}

flatlaf-intellij-themes/build.gradle.kts

@@ -16,6 +16,7 @@
 
 plugins {
 	`java-library`
+	`flatlaf-module-info`
 	`maven-publish`
 	id( "com.jfrog.bintray" )
 	id( "com.jfrog.artifactory" )
@@ -25,16 +26,8 @@ dependencies {
 	implementation( project( ":flatlaf-core" ) )
 }
 
-if( JavaVersion.current() >= JavaVersion.VERSION_1_9 ) {
-	sourceSets {
-		create( "module-info" ) {
-			java {
-				// include "src/main/java" here to get compile errors if classes are
-				// used from other modules that are not specified in module dependencies
-				setSrcDirs( listOf( "src/main/module-info", "src/main/java" ) )
-			}
-		}
-	}
+flatlafModuleInfo {
+	dependsOn( ":flatlaf-core:jar" )
 }
 
 java {
@@ -43,26 +36,6 @@ java {
 }
 
 tasks {
-	if( JavaVersion.current() >= JavaVersion.VERSION_1_9 ) {
-		named<JavaCompile>( "compileModuleInfoJava" ) {
-			sourceCompatibility = "9"
-			targetCompatibility = "9"
-
-			dependsOn( ":flatlaf-core:jar" )
-
-			options.compilerArgs.add( "--module-path" )
-			options.compilerArgs.add( project( ":flatlaf-core" ).tasks["jar"].outputs.files.asPath )
-		}
-	}
-
-	jar {
-		if( JavaVersion.current() >= JavaVersion.VERSION_1_9 ) {
-			from( sourceSets["module-info"].output ) {
-				include( "module-info.class" )
-			}
-		}
-	}
-
 	javadoc {
 		options {
 			this as StandardJavadocDocletOptions