Merge PR #779: macOS: window title bar close/minimize/zoom buttons spacing

2025-12-06 05:50:53 +03:00 · 2024-01-25 14:06:38 +01:00
parent cf44a5c50b 3465fa68b4
commit ca514dd76e
16 changed files with 1481 additions and 100 deletions
--- a/flatlaf-natives/flatlaf-natives-macos/src/main/headers/JNIUtils.h
+++ b/flatlaf-natives/flatlaf-natives-macos/src/main/headers/JNIUtils.h
@@ -41,4 +41,6 @@
 	}


-jfieldID getFieldID( JNIEnv *env, const char* className, const char* fieldName, const char* fieldSignature );
+jclass findClass( JNIEnv *env, const char* className, bool globalRef );
+jfieldID getFieldID( JNIEnv *env, const char* className, const char* fieldName, const char* fieldSignature, bool staticField );
+jmethodID getMethodID( JNIEnv *env, jclass cls, const char* methodName, const char* methodSignature, bool staticMethod );
--- a/flatlaf-natives/flatlaf-natives-macos/src/main/headers/com_formdev_flatlaf_ui_FlatNativeMacLibrary.h
+++ b/flatlaf-natives/flatlaf-natives-macos/src/main/headers/com_formdev_flatlaf_ui_FlatNativeMacLibrary.h
@@ -7,6 +7,12 @@
 #ifdef __cplusplus
 extern "C" {
 #endif
+#undef com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_DEFAULT
+#define com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_DEFAULT 0L
+#undef com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_MEDIUM
+#define com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_MEDIUM 1L
+#undef com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_LARGE
+#define com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_LARGE 2L
 /*
 * Class:     com_formdev_flatlaf_ui_FlatNativeMacLibrary
 * Method:    setWindowRoundedBorder
@@ -15,6 +21,38 @@ extern "C" {
 JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_setWindowRoundedBorder
  (JNIEnv *, jclass, jobject, jfloat, jfloat, jint);

+/*
+ * Class:     com_formdev_flatlaf_ui_FlatNativeMacLibrary
+ * Method:    setWindowButtonsSpacing
+ * Signature: (Ljava/awt/Window;I)Z
+ */
+JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_setWindowButtonsSpacing
+  (JNIEnv *, jclass, jobject, jint);
+
+/*
+ * Class:     com_formdev_flatlaf_ui_FlatNativeMacLibrary
+ * Method:    getWindowButtonsBounds
+ * Signature: (Ljava/awt/Window;)Ljava/awt/Rectangle;
+ */
+JNIEXPORT jobject JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_getWindowButtonsBounds
+  (JNIEnv *, jclass, jobject);
+
+/*
+ * Class:     com_formdev_flatlaf_ui_FlatNativeMacLibrary
+ * Method:    isWindowFullScreen
+ * Signature: (Ljava/awt/Window;)Z
+ */
+JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_isWindowFullScreen
+  (JNIEnv *, jclass, jobject);
+
+/*
+ * Class:     com_formdev_flatlaf_ui_FlatNativeMacLibrary
+ * Method:    toggleWindowFullScreen
+ * Signature: (Ljava/awt/Window;)Z
+ */
+JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_toggleWindowFullScreen
+  (JNIEnv *, jclass, jobject);
+
 #ifdef __cplusplus
 }
 #endif
--- a/flatlaf-natives/flatlaf-natives-macos/src/main/objcpp/JNIUtils.mm
+++ b/flatlaf-natives/flatlaf-natives-macos/src/main/objcpp/JNIUtils.mm
@@ -21,8 +21,8 @@
 * @author Karl Tauber
 */

-jfieldID getFieldID( JNIEnv *env, const char* className, const char* fieldName, const char* fieldSignature ) {
-//	NSLog( @"getFieldID %s %s %s", className, fieldName, fieldSignature );
+jclass findClass( JNIEnv *env, const char* className, bool globalRef ) {
+//	NSLog( @"findClass %s", className );

 	jclass cls = env->FindClass( className );
 	if( cls == NULL ) {
@@ -32,7 +32,22 @@ jfieldID getFieldID( JNIEnv *env, const char* className, const char* fieldName,
 		return NULL;
 	}

-	jfieldID fieldID = env->GetFieldID( cls, fieldName, fieldSignature );
+	if( globalRef )
+		cls = reinterpret_cast<jclass>( env->NewGlobalRef( cls ) );
+
+	return cls;
+}
+
+jfieldID getFieldID( JNIEnv *env, const char* className, const char* fieldName, const char* fieldSignature, bool staticField ) {
+//	NSLog( @"getFieldID %s %s %s", className, fieldName, fieldSignature );
+
+	jclass cls = findClass( env, className, false );
+	if( cls == NULL )
+		return NULL;
+
+	jfieldID fieldID = staticField
+		? env->GetStaticFieldID( cls, fieldName, fieldSignature )
+		: env->GetFieldID( cls, fieldName, fieldSignature );
 	if( fieldID == NULL ) {
 		NSLog( @"FlatLaf: failed to lookup field '%s' of type '%s' in class '%s'", fieldName, fieldSignature, className );
 		env->ExceptionDescribe(); // print stack trace
@@ -42,3 +57,22 @@ jfieldID getFieldID( JNIEnv *env, const char* className, const char* fieldName,

 	return fieldID;
 }
+
+jmethodID getMethodID( JNIEnv *env, jclass cls, const char* methodName, const char* methodSignature, bool staticMethod ) {
+//	NSLog( @"getMethodID %s %s", methodName, methodSignature );
+
+	if( cls == NULL )
+		return NULL;
+
+	jmethodID methodID = staticMethod
+		? env->GetStaticMethodID( cls, methodName, methodSignature )
+		: env->GetMethodID( cls, methodName, methodSignature );
+	if( methodID == NULL ) {
+		NSLog( @"FlatLaf: failed to lookup method '%s' of type '%s'", methodName, methodSignature );
+		env->ExceptionDescribe(); // print stack trace
+		env->ExceptionClear();
+		return NULL;
+	}
+
+	return methodID;
+}
--- a/flatlaf-natives/flatlaf-natives-macos/src/main/objcpp/MacWindow.mm
+++ b/flatlaf-natives/flatlaf-natives-macos/src/main/objcpp/MacWindow.mm
@@ -15,6 +15,7 @@
 */

 #import <Cocoa/Cocoa.h>
+#import <objc/runtime.h>
 #import <jni.h>
 #import "JNIUtils.h"
 #import "JNFRunLoop.h"
@@ -24,14 +25,37 @@
 * @author Karl Tauber
 */

+@interface WindowData : NSObject
+	// used when window is full screen
+	@property (nonatomic) int lastWindowButtonAreaWidth;
+	@property (nonatomic) int lastWindowTitleBarHeight;
+
+	// full screen observers
+	@property (nonatomic) id willEnterFullScreenObserver;
+	@property (nonatomic) id willExitFullScreenObserver;
+	@property (nonatomic) id didExitFullScreenObserver;
+@end
+
+@implementation WindowData
+@end
+
+// declare internal methods
+NSWindow* getNSWindow( JNIEnv* env, jclass cls, jobject window );
+WindowData* getWindowData( NSWindow* nsWindow, bool allocate );
+void setWindowButtonsHidden( NSWindow* nsWindow, bool hidden );
+int getWindowButtonAreaWidth( NSWindow* nsWindow );
+int getWindowTitleBarHeight( NSWindow* nsWindow );
+bool isWindowFullScreen( NSWindow* nsWindow );
+
+
 NSWindow* getNSWindow( JNIEnv* env, jclass cls, jobject window ) {
 	if( window == NULL )
 		return NULL;

-	// initialize field IDs (done only once because fields are static)
-	static jfieldID peerID = getFieldID( env, "java/awt/Component", "peer", "Ljava/awt/peer/ComponentPeer;" );
-	static jfieldID platformWindowID = getFieldID( env, "sun/lwawt/LWWindowPeer", "platformWindow", "Lsun/lwawt/PlatformWindow;" );
-	static jfieldID ptrID = getFieldID( env, "sun/lwawt/macosx/CFRetainedResource", "ptr", "J" );
+	// initialize field IDs (done only once because variables are static)
+	static jfieldID peerID = getFieldID( env, "java/awt/Component", "peer", "Ljava/awt/peer/ComponentPeer;", false );
+	static jfieldID platformWindowID = getFieldID( env, "sun/lwawt/LWWindowPeer", "platformWindow", "Lsun/lwawt/PlatformWindow;", false );
+	static jfieldID ptrID = getFieldID( env, "sun/lwawt/macosx/CFRetainedResource", "ptr", "J", false );
 	if( peerID == NULL || platformWindowID == NULL || ptrID == NULL )
 		return NULL;

@@ -49,6 +73,16 @@ NSWindow* getNSWindow( JNIEnv* env, jclass cls, jobject window ) {
 	return (NSWindow *) jlong_to_ptr( env->GetLongField( platformWindow, ptrID ) );
 }

+WindowData* getWindowData( NSWindow* nsWindow, bool allocate ) {
+	static char key;
+	WindowData* windowData = objc_getAssociatedObject( nsWindow, &key );
+	if( windowData == NULL && allocate ) {
+		windowData = [WindowData new];
+		objc_setAssociatedObject( nsWindow, &key, windowData, OBJC_ASSOCIATION_RETAIN_NONATOMIC );
+	}
+	return windowData;
+}
+
 extern "C"
 JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_setWindowRoundedBorder
 	( JNIEnv* env, jclass cls, jobject window, jfloat radius, jfloat borderWidth, jint borderColor )
@@ -87,3 +121,259 @@ JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_setW
 	JNI_COCOA_EXIT()
 	return FALSE;
 }
+
+extern "C"
+JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_setWindowButtonsSpacing
+	( JNIEnv* env, jclass cls, jobject window, jint buttonsSpacing )
+{
+	JNI_COCOA_ENTER()
+
+	NSWindow* nsWindow = getNSWindow( env, cls, window );
+	if( nsWindow == NULL )
+		return FALSE;
+
+	#define SPACING_DEFAULT com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_DEFAULT
+	#define SPACING_MEDIUM  com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_MEDIUM
+	#define SPACING_LARGE   com_formdev_flatlaf_ui_FlatNativeMacLibrary_BUTTONS_SPACING_LARGE
+
+	bool isMacOS_11_orLater = @available( macOS 11, * );
+	if( !isMacOS_11_orLater && buttonsSpacing == SPACING_LARGE )
+		buttonsSpacing = SPACING_MEDIUM;
+	int oldButtonsSpacing = (nsWindow.toolbar != NULL)
+		? ((isMacOS_11_orLater && nsWindow.toolbarStyle == NSWindowToolbarStyleUnified)
+			? SPACING_LARGE
+			: SPACING_MEDIUM)
+		: SPACING_DEFAULT;
+
+	if( buttonsSpacing == oldButtonsSpacing )
+		return TRUE;
+
+	WindowData* windowData = getWindowData( nsWindow, true );
+
+	[FlatJNFRunLoop performOnMainThreadWaiting:YES withBlock:^(){
+//		NSLog( @"\n%@\n\n", [nsWindow.contentView.superview _subtreeDescription] );
+
+		// add/remove toolbar
+		NSToolbar* toolbar = NULL;
+		bool needsToolbar = (buttonsSpacing != SPACING_DEFAULT);
+		if( needsToolbar ) {
+			toolbar = [NSToolbar new];
+			toolbar.showsBaselineSeparator = NO; // necessary for older macOS versions
+			if( isWindowFullScreen( nsWindow ) )
+				toolbar.visible = NO;
+		}
+		nsWindow.toolbar = toolbar;
+
+		if( isMacOS_11_orLater ) {
+			nsWindow.toolbarStyle = (buttonsSpacing == SPACING_LARGE)
+				? NSWindowToolbarStyleUnified
+				: (buttonsSpacing == SPACING_MEDIUM)
+					? NSWindowToolbarStyleUnifiedCompact
+					: NSWindowToolbarStyleAutomatic;
+		}
+
+		windowData.lastWindowButtonAreaWidth = 0;
+		windowData.lastWindowTitleBarHeight = 0;
+
+//		NSLog( @"\n%@\n\n", [nsWindow.contentView.superview _subtreeDescription] );
+
+		// when window becomes full screen, it is necessary to hide the toolbar
+		// because it otherwise is shown non-transparent and hides Swing components
+		NSNotificationCenter* center = [NSNotificationCenter defaultCenter];
+		if( needsToolbar && windowData.willEnterFullScreenObserver == NULL ) {
+//			NSLog( @"add observers %@", nsWindow );
+			windowData.willEnterFullScreenObserver = [center addObserverForName:NSWindowWillEnterFullScreenNotification
+				object:nsWindow queue:nil usingBlock:^(NSNotification *note) {
+//					NSLog( @"enter full screen %@", nsWindow );
+					if( nsWindow.toolbar != NULL ) {
+						// remember button area width, which is used later when window exits full screen
+						// remembar title bar height so that "main" JToolBar keeps its height in full screen
+						windowData.lastWindowButtonAreaWidth = getWindowButtonAreaWidth( nsWindow );
+						windowData.lastWindowTitleBarHeight = getWindowTitleBarHeight( nsWindow );
+//						NSLog( @"%d %d", windowData.lastWindowButtonAreaWidth, windowData.lastWindowTitleBarHeight );
+
+						nsWindow.toolbar.visible = NO;
+					}
+				}];
+
+			windowData.willExitFullScreenObserver = [center addObserverForName:NSWindowWillExitFullScreenNotification
+				object:nsWindow queue:nil usingBlock:^(NSNotification *note) {
+//					NSLog( @"will exit  full screen %@", nsWindow );
+					if( nsWindow.toolbar != NULL )
+						setWindowButtonsHidden( nsWindow, true );
+				}];
+
+			windowData.didExitFullScreenObserver = [center addObserverForName:NSWindowDidExitFullScreenNotification
+				object:nsWindow queue:nil usingBlock:^(NSNotification *note) {
+//					NSLog( @"exit  full screen %@", nsWindow );
+					if( nsWindow.toolbar != NULL ) {
+						setWindowButtonsHidden( nsWindow, false );
+						nsWindow.toolbar.visible = YES;
+					}
+
+					windowData.lastWindowButtonAreaWidth = 0;
+					windowData.lastWindowTitleBarHeight = 0;
+				}];
+		} else if( !needsToolbar ) {
+//			NSLog( @"remove observers %@", nsWindow );
+			if( windowData.willEnterFullScreenObserver != NULL ) {
+				[center removeObserver:windowData.willEnterFullScreenObserver];
+				windowData.willEnterFullScreenObserver = nil;
+			}
+			if( windowData.willExitFullScreenObserver != NULL ) {
+				[center removeObserver:windowData.willExitFullScreenObserver];
+				windowData.willExitFullScreenObserver = nil;
+			}
+			if( windowData.didExitFullScreenObserver != NULL ) {
+				[center removeObserver:windowData.didExitFullScreenObserver];
+				windowData.didExitFullScreenObserver = nil;
+			}
+		}
+	}];
+
+	return TRUE;
+
+	JNI_COCOA_EXIT()
+	return FALSE;
+}
+
+void setWindowButtonsHidden( NSWindow* nsWindow, bool hidden ) {
+	// get buttons
+	NSView* buttons[3] = {
+		[nsWindow standardWindowButton:NSWindowCloseButton],
+		[nsWindow standardWindowButton:NSWindowMiniaturizeButton],
+		[nsWindow standardWindowButton:NSWindowZoomButton]
+	};
+
+	for( int i = 0; i < 3; i++ ) {
+		NSView* button = buttons[i];
+		if( button != NULL )
+			button.hidden = hidden;
+	}
+}
+
+extern "C"
+JNIEXPORT jobject JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_getWindowButtonsBounds
+	( JNIEnv* env, jclass cls, jobject window )
+{
+	JNI_COCOA_ENTER()
+
+	NSWindow* nsWindow = getNSWindow( env, cls, window );
+	if( nsWindow == NULL )
+		return NULL;
+
+	WindowData* windowData = getWindowData( nsWindow, false );
+	int width = 0;
+	int height = 0;
+
+	// get width
+	if( isWindowFullScreen( nsWindow ) ) {
+		// use zero if window is full screen because close/minimize/zoom buttons are hidden
+		width = 0;
+	} else if( windowData != NULL && windowData.lastWindowButtonAreaWidth > 0 ) {
+		// use remembered value if window is in transition from full screen to non-full screen
+		// because NSToolbar is not yet visible
+		width = windowData.lastWindowButtonAreaWidth;
+	} else
+		width = getWindowButtonAreaWidth( nsWindow );
+
+	// get height
+	if( windowData != NULL && windowData.lastWindowTitleBarHeight > 0 ) {
+		// use remembered value if window is full screen because NSToolbar is hidden
+		height = windowData.lastWindowTitleBarHeight;
+	} else
+		height = getWindowTitleBarHeight( nsWindow );
+
+	// initialize class and method ID (done only once because variables are static)
+	static jclass cls = findClass( env, "java/awt/Rectangle", true );
+	static jmethodID methodID = getMethodID( env, cls, "<init>", "(IIII)V", false );
+	if( cls == NULL || methodID == NULL )
+		return NULL;
+
+	// create and return Rectangle
+	return env->NewObject( cls, methodID, 0, 0, width, height );
+
+	JNI_COCOA_EXIT()
+	return NULL;
+}
+
+int getWindowButtonAreaWidth( NSWindow* nsWindow ) {
+	// get buttons
+	NSView* buttons[3] = {
+		[nsWindow standardWindowButton:NSWindowCloseButton],
+		[nsWindow standardWindowButton:NSWindowMiniaturizeButton],
+		[nsWindow standardWindowButton:NSWindowZoomButton]
+	};
+
+	// get most left and right coordinates
+	int left = -1;
+	int right = -1;
+	for( int i = 0; i < 3; i++ ) {
+		NSView* button = buttons[i];
+		if( button == NULL )
+			continue;
+
+		int x = [button convertRect: [button bounds] toView:button.superview].origin.x;
+		int width = button.bounds.size.width;
+		if( left == -1 || x < left )
+			left = x;
+		if( right == -1 || x + width > right )
+			right = x + width;
+	}
+
+	if( left == -1 || right == -1 )
+		return -1;
+
+	// 'right' is the actual button area width (from left window edge)
+	// adding 'left' to add same empty space on right side as on left side
+	return right + left;
+}
+
+int getWindowTitleBarHeight( NSWindow* nsWindow ) {
+	NSView* closeButton = [nsWindow standardWindowButton:NSWindowCloseButton];
+	if( closeButton == NULL )
+		return -1;
+
+	NSView* titlebar = closeButton.superview;
+	return titlebar.bounds.size.height;
+}
+
+extern "C"
+JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_isWindowFullScreen
+	( JNIEnv* env, jclass cls, jobject window )
+{
+	JNI_COCOA_ENTER()
+
+	NSWindow* nsWindow = getNSWindow( env, cls, window );
+	if( nsWindow == NULL )
+		return FALSE;
+
+	return (jboolean) isWindowFullScreen( nsWindow );
+
+	JNI_COCOA_EXIT()
+	return FALSE;
+}
+
+bool isWindowFullScreen( NSWindow* nsWindow ) {
+	return ((nsWindow.styleMask & NSWindowStyleMaskFullScreen) != 0);
+}
+
+extern "C"
+JNIEXPORT jboolean JNICALL Java_com_formdev_flatlaf_ui_FlatNativeMacLibrary_toggleWindowFullScreen
+	( JNIEnv* env, jclass cls, jobject window )
+{
+	JNI_COCOA_ENTER()
+
+	NSWindow* nsWindow = getNSWindow( env, cls, window );
+	if( nsWindow == NULL )
+		return FALSE;
+
+	[FlatJNFRunLoop performOnMainThreadWaiting:NO withBlock:^(){
+		[nsWindow toggleFullScreen:nil];
+	}];
+
+	return TRUE;
+
+	JNI_COCOA_EXIT()
+	return FALSE;
+}