mirror of
https://github.com/JFormDesigner/FlatLaf.git
synced 2025-12-06 22:10:54 +03:00
df8212b49e
- default is now Java 8 toolchain (to fix Eclipse project import) - `src/main/module-info` and `src/main/java9` are compiled with Java 11 toolchain (if global toolchain is Java 8) - `src/main/module-info` and `src/main/java9` are no longer imported into Eclipse projects - task `errorprone` now uses at least Java 11 toolchain
63 lines
1.6 KiB
Kotlin
63 lines
1.6 KiB
Kotlin
/*
|
|
* Copyright 2020 FormDev Software GmbH
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* https://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
plugins {
|
|
java
|
|
}
|
|
|
|
// for Eclipse IDE project import, exclude if:
|
|
// - plugin "eclipse" is applied; e.g. if running in Eclipse IDE with buildship plugin
|
|
// - no taskNames specified at command line; e.g. if buildship synchronizes projects
|
|
val exclude =
|
|
rootProject.plugins.hasPlugin( "eclipse" ) &&
|
|
gradle.startParameter.taskNames.isEmpty()
|
|
|
|
if( !exclude ) {
|
|
sourceSets {
|
|
create( "java9" ) {
|
|
java {
|
|
setSrcDirs( listOf( "src/main/java9" ) )
|
|
}
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
add( "java9Implementation", sourceSets.main.get().output )
|
|
}
|
|
|
|
tasks {
|
|
named<JavaCompile>( "compileJava9Java" ) {
|
|
sourceCompatibility = "9"
|
|
targetCompatibility = "9"
|
|
|
|
// if global toolchain is Java 8, then use Java 11 to build
|
|
if( java.toolchain.languageVersion.get().asInt() < 9 ) {
|
|
javaCompiler.set( javaToolchains.compilerFor {
|
|
languageVersion.set( JavaLanguageVersion.of( 11 ) )
|
|
} )
|
|
}
|
|
}
|
|
|
|
jar {
|
|
manifest.attributes( "Multi-Release" to "true" )
|
|
|
|
into( "META-INF/versions/9" ) {
|
|
from( sourceSets["java9"].output )
|
|
}
|
|
}
|
|
}
|
|
}
|