mirror of
https://github.com/JFormDesigner/FlatLaf.git
synced 2025-12-06 14:00:55 +03:00
056da35758
Some checks failed
CI / build (11) (push) Has been cancelled
CI / build-on (17) (push) Has been cancelled
CI / build-on (21) (push) Has been cancelled
CI / build-on (25) (push) Has been cancelled
CI / build-on (8) (push) Has been cancelled
CI / snapshot (push) Has been cancelled
CI / release (push) Has been cancelled
Fonts / Fonts (inter) (push) Has been cancelled
Fonts / Fonts (jetbrains-mono) (push) Has been cancelled
Fonts / Fonts (roboto) (push) Has been cancelled
Fonts / Fonts (roboto-mono) (push) Has been cancelled
Native Libraries / Natives (macos-latest) (push) Has been cancelled
Native Libraries / Natives (ubuntu-24.04-arm) (push) Has been cancelled
Native Libraries / Natives (ubuntu-latest) (push) Has been cancelled
Native Libraries / Natives (windows-latest) (push) Has been cancelled
- always use Java toolchains - default is Java 11 (but source/targetCompatibility is still 1.8) - use system property `toolchain` (e.g. `-Dtoolchain=25`) to compile with other Java versions preparation for Gradle 9.x, which requires Java 17+ to run
69 lines
2.1 KiB
Kotlin
69 lines
2.1 KiB
Kotlin
/*
|
|
* Copyright 2019 FormDev Software GmbH
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* https://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
|
|
plugins {
|
|
`java-library`
|
|
`flatlaf-toolchain`
|
|
}
|
|
|
|
dependencies {
|
|
implementation( project( ":flatlaf-core" ) )
|
|
implementation( project( ":flatlaf-extras" ) )
|
|
implementation( project( ":flatlaf-fonts-inter" ) )
|
|
implementation( project( ":flatlaf-fonts-jetbrains-mono" ) )
|
|
implementation( project( ":flatlaf-fonts-roboto" ) )
|
|
implementation( project( ":flatlaf-fonts-roboto-mono" ) )
|
|
implementation( project( ":flatlaf-intellij-themes" ) )
|
|
implementation( libs.miglayout.swing )
|
|
implementation( libs.jgoodies.forms )
|
|
// implementation( project( ":flatlaf-natives-jna" ) )
|
|
}
|
|
|
|
tasks {
|
|
jar {
|
|
dependsOn( ":flatlaf-core:jar" )
|
|
dependsOn( ":flatlaf-extras:jar" )
|
|
dependsOn( ":flatlaf-fonts-inter:jar" )
|
|
dependsOn( ":flatlaf-fonts-jetbrains-mono:jar" )
|
|
dependsOn( ":flatlaf-fonts-roboto:jar" )
|
|
dependsOn( ":flatlaf-fonts-roboto-mono:jar" )
|
|
dependsOn( ":flatlaf-intellij-themes:jar" )
|
|
// dependsOn( ":flatlaf-natives-jna:jar" )
|
|
|
|
manifest {
|
|
attributes( "Main-Class" to "com.formdev.flatlaf.demo.FlatLafDemo" )
|
|
|
|
if( java.toolchain.languageVersion.get().asInt() >= 9 )
|
|
attributes( "Multi-Release" to "true" )
|
|
|
|
// allow loading FlatLaf native library in Java 24+ (see https://openjdk.org/jeps/472)
|
|
attributes( "Enable-Native-Access" to "ALL-UNNAMED" )
|
|
}
|
|
|
|
exclude( "module-info.class" )
|
|
exclude( "META-INF/versions/*/module-info.class" )
|
|
|
|
// include all dependencies in jar
|
|
from( {
|
|
configurations.runtimeClasspath.get()
|
|
.filter { it.name.endsWith( "jar" ) }
|
|
.map { zipTree( it ).matching {
|
|
exclude( "META-INF/LICENSE" )
|
|
} }
|
|
} )
|
|
}
|
|
}
|